UTN - FRCU

Tutorial de Maple Para Anlisis Matemtico I

Introduccion a Maple
Que es Maple?
Maple es una herramienta para la solucin completa de variados problemas matemticos.
Con ms de 3000 comandos puede resolver clculos aritmticos elementales o bien
problemas avanzados de anlisis tensorial o teora de grupos. Su interfaz permite el
ingreso de las expresiones matemticas tanto en notacin csica de las computadoras,
como en el lenguaje propio de las matemticas.
Objetivo
Adquirir la destreza necesaria para resolver problemas de clculo infinitesimal con el
sistema Maple 8.00
Utilizar el programa para la representacin de funciones, clculo de lmites, derivadas,
integrales, determinacin de extremos. Resolucin de ecuaciones, etc
Trabajando con Maple
Generalidades
Los archivos creados con este programa tienen la extensin *.mws. El area de trabajo o
worksheet es similar a la de muchas otras aplicaciones de windows. En la primera lnea
aparece el prompt de Maple: el carcter "mayor que" (>). Esto quiere decir que el programa
est listo para recibir instrucciones. En esta hoja se permite disponer de zonas o regiones
de entrada, de salida y de texto.
La entrada puede efectuarse de dos maneras diferentes: maple notation o standard math. Las
entradas de expresiones a resolver se visualizan en rojo y los resultados en azul.
Menes
La mayora de los menes tienen las facilidades comunes de las aplicaciones windows. Si
bien los tems especficos se irn desarrollando en oportunidad de analizar su uso, en este
momento es importante sealar que:
los documentos Maple puede exportarse en diversos formatos (por ejemplo: rtf para
leer con word), ver las opciones en el men File..Export As..
es posible cambiar los tipos, tamaos y colores de los caractres, prrafos,etc; ver las
opciones en el men Format.. Styles..
En el men Insert, los cuatro primeros items indican el tipo de entrada que se
efectuar a continuacin de su seleccin.
Si se trabaja con standard math en el men View .. Palettes se encuentran las
facilidades para ingresar expresiones.
Cuando los comandos del programa se escriben en maysculas no evalan lo
solicitado sino que, simplemente, expresan la sentencia de acuerdo a la notacin
general definida en la opcin Preference del men File.
En el men View, y en ltimo lugar, se encuentran los tems Expand All Sections y
1
Collapse All Sections. A travs de ellos puede abrir y cerrar todas secciones del
presente documento; al cerrarlas tendr un ndice del contenido
global.
Ahora usted debera ejecutar File, New e ingresar a los diferentes items de men, para
comenzar a familiarizarse con ellos.
Luego deber ir al menu Window y seleccionar la primera de las ventanas abiertas para
regresar a este documento
Introduccin de Expresiones
Trabajando con la notacin de Maple cada sentencia a ser evaluada debe terminar con un ";" , si
se trabaja en standard math no es necesario ste smbolo. El ltimo resultado o salida obtenido
del programa puede recuperarse para ser utilizado en una instruccin posterior, por medio del
carcter porcentaje (%). De forma anloga, (%%) representa el penltimo resultado y (%%%)
el antepenltimo resultado.
Operaciones Aritmticas
Los siguientes son ejemplos que muestran las operaciones de suma, multiplicacin,
divisin, potencia y raiz cuadrada. Posicione el cursor en cualquier lugar sobre la
expresin a evaluar y pulse la tecla enter:
> 3+4;
> 3*4;
> 12/4;
> 3^4;
> sqrt(16);
Ahora en el men Edit seleccione el item Remove Output .. from WorkSheet .
Los siguientes son ejemplos que muestran otras operaciones, como as tambin el uso
de constantes. Puede evaluarlas ahora:
> sqrt(2);
Vemos que no obtuvimos el resultado esperado, esto es porque Maple busca siempre
no cometer errores de redondeo. Las operaciones aritmticas sern realizadas cuando el
usuario lo decida, clickeando con el botn derecho sobre la expresin de salida de
Maple y seleccionando Approximate del men que se despliega y eligiendo despus el
nmero de cifras totales que se quiere en el resultado (por defecto las operaciones se
hacen con 10 cifras). Otra forma de realizar la operacin es mediante el comando evalf,
que admite como segundo argumento opcional el nmero de dgitos:
> evalf(sqrt(2),30);
> evalf(ln(15));evalf(log[2](8));evalf(exp(5));
2
Las constantes , e, i,
Pi representa la constante , en los clculos debe ingresarse Pi. Evale ahora las
siguientes expresiones:
> evalf(sin(Pi/5));
> evalf(Pi);
> evalf(pi);
Para obtener la constante e (base de los logaritmos naturales) debe ingresarse exp(1).
Evale ahora las siguientes expresiones:
> ln(exp(1));
> exp(4);
> evalf(%);
Para trabajar con nmeros complejos la constante i se representa por I. Evale ahora las
siguientes expresiones:
> (10+5*I)*(3+4*I);
Para Trabajar con el smbolo debe ingresarse infinity Evale ahora las siguientes
expresiones:
> limit(x,x=infinity);
> limit(-x,x=infinity);
Ahora usted puede resolver la prctica de operaciones aritmticas
Expresiones Algebraicas
Para introducir expresiones algebraicas se deben seguir las operaciones aritmticas
descriptas mas arriba. Por ejemplo para intoducir el polinomio
:= ( ) p x + + 3 x 7 x
2
3 x
3
7 x
4
, se debe ingresar la siguiente sentencia (el smbolo :=es el
operador de asignacin) :
> p(x):= -3*x+7*x^2-3*x^3+7*x^4;
Los siguientes comandos factorizan y calculan el producto de expresiones algebraicas:
> factor(%);
> expand(%);
Para hallar las races de polinomios se utiliza el comando solve, que resulve la ecuacin p(x)
= 0 y donde cada raz aparece en el resultado de acuerdo a su multiplicidad, o bien el
comando roots para el cual cada raz aparece en el resultado seguida de su multiplicidad:
> solve(x^4-3*x^3+3*x^2-x);
3
> roots(x^4-3*x^3+3*x^2-x);
Para especializar el polinomio llamado p(x) en un valor determinado, se utiliza el comando
subs:
> subs(x=1,p(x));
Para simplificar expresiones racionales, se utiliza el la funcin normal:
> normal((x^2-4)/(x-2)^3);
Ahora usted puede resolver la prctica de expresiones algebraicas
Expresiones Trascendentes
El comando simplify se usa para simplificar algunos tipo de expresiones. Si slo se le da un
argumento, busca la expresin mas sencilla asociada a la funcin ingresada, se pueden dar
tambin opciones adicionales:
> e := cos(x)^5 + sin(x)^4 + 2*cos(x)^2 - 2*sin(x)^2 -
cos(2*x);
simplify(e);
> simplify(sin(x)^2+cos(x)^2);
> simplify(sqrt(x^2),assume=real);
> simplify(sqrt(x^2),assume=positive);
Ecuaciones e inecuaciones
Para resolver ecuaciones ya se ha descrito el comando solve, aqu se incorporan algunos
otros ejemplos del uso del comando para la solucin de sistemas de ecuaciones:
> solve({x+y=1, 2*x+y=3}, {x,y});
> eqns := {u+v+w=1, 3*u+v=3, u-2*v-w=0};
> sols := solve( eqns );
como tambin la forma de introducir inecuaciones y leer sus resultados:
a) el resultado de la inecuacin < 0 + x
1
x
es el intervalo (0,) :
> solve(x+1/x > 0, x);
b) el resultado de la inecuacin 2
+ 3 5 x
2 x
es la unin de los intervalos (,-7/3], [1/7,2)
y (2,)
4
> solve(abs((3+5*x)/(2-x))>= 2, x);
Ahora usted puede resolver los ejercicios 3 y 4 de la prctica del Mdulo I
Funciones
Definicin de Funciones
Como se indica en expresiones algebraicas para definir la funcin := ( ) f x ( ) tg x
2
basta con
ingresar:

> f:=tan(x^2);
o bien la expresin donde se evidencia la variable independiente:
> f:=x->tan(x^2);
Para asignar una funcin definida por partes, debe ingresarse cada condicin seguida de la
expresin de la funcin, y todas las expresiones separadas por una coma, con el comando
piecewise de la siguiente manera:
> f(x):= piecewise (x<0,x,x>=0 and x<1,-2,x>=1,x^2);
Maple tiene libreras propias con funciones predefinidas, una de ellas es la librera de
grficos (plotools), que se cargar ahora. Como ejemplo graficaremos un crculo con
centro en (2,1) y radio 1, utilizando el comando display para ver el grafico resuelto:
> with(plottools);
> plots[display](circle([0,1],1,color=red));
Para ver los nombres Maple de las funciones mas usadas haga click aqu .
Para hallar el valor numrico de una funcin en un punto es suficiente definir la funcin y
luego especilizarla en el valor deseado:
> f(x):= x^2+3*x-2;
> evalf(subs(x=2,f(x)));
Puede resolver ahora los ejercicios sobre grficas de las pginas 5,6,8, del Mdulo 2.
Ceros de una funcin
Para hallar los ceros de una funcin ya se ha descrito el comando solve, aqu se presenta el
comando fsolve que d la solucin, o cero de la funcin resolviendo el clculo aritmtico
(sin necesidad de usar el comanddo evalf) . Las soluciones se dan en el intervalo [-,]
5
> fsolve(tan(sin(x))=0,x);
> fsolve(tan(sin(x))-1=0,x);
Tambin es posible pedirle al comando que halle los ceros , pero slo en un intervalo
determinado:
> p(x) := 23*x^5 + 105*x^4 - 10*x^2 +
17*x:fsolve(p(x),x,-1..1 );
Aritmtica de funciones
Para la suma, resta, multiplicacin y divisn de funciones se utilizan los operadores ya vistos,
as:
> f(x):= 2*x^2-3*x;g(x):= sin(x);
> f+g=f(x)+g(x);f-g=f(x)-g(x);fg=f(x)*g(x);f/g=f(x)/g(x);
La composicin de funciones tiene por operador el smbolo @:
> restart:
> ((x^2+1)@sin)(x);(cos@(x^3-2*x))(x);
Este mismo operador repetido, se usa para ejecutar la composicin reiterada, indicando con
un nmero la cantidad de veces a componer. Cuando se indica un nmero negativo el
programa entiende que debe componer la inversa de la funcin dada, la cantidad de veces
que se indica:
> (sin@@2)(x);
> (sin@@(-1))(x);
> (cos@@(-2))(x);
Ahora usted puede resolver los ejercicios correspondientes, de las pginas 5,12 y 14 del
Mdulo 2.
Representacin grfica de funciones en coordenadas cartesianas
I nicio
Para trabajar con grficas conviene, en primer lugar limpiar la memoria del programa
y luego cargar las libreras para grficos:
> restart;
> with(plots);
> with(plottools);
Grficas
6
Para representar graficamente una funcin se utiliza el comando plot, al cual hay que
indicarle la funcin a representar y cual es la variable independiente:
> f:=x->tan(x^2); # definimos la funcin a representar
> plot(f(x),x);
Se puede indicar el intervalo que se va a dibujar y el estilo de lnea sobre el grfico (en
color, en lnea de trazos, etc.); estos parmetros se pueden modificar seleccionando el
item de men style que se despliega con el botn derecho del mouse aplicado sobre el
gfico, por ejemplo:
> plot(f(x),x=-1..1,color=magenta,linestyle=1);
Es posible tener distintas vistas de la grfica de una funcin, dando adems el intervalo
correspondiente a la variable dependiente, ejecute ahora las siguientes instrucciones:
> plot((sin(x^2)+4)/ln(9),x=-5..5);
> plot((sin(x^2)+4)/ln(9),x=-5..5,y=1..5);
Comparacin de grficos
Si se desea comparar el grfico de diversas funciones, se pueden pedir los grficos de
las siguientes posibles formas:
a) encerrando entre corchetes la lista de funciones a graficar, que pueden ser definidas
previamente:
> plot([(sin(x-Pi/2)/2)+1,(sin(x+Pi/2)/2)+1,(sin(x+Pi)/2)
+1],x=-2*Pi..2*Pi,legend=[f1,f2,f3]);
b) definiendo previamente las grficas y solicitando su visualizacin despus. El
smbolo ":" indica la evaluacin de la expresin sin desplegar los resultados, as:
> restart: with(plots):
> a1:=
plot((sin(x-Pi/2)/2)+1,x=-2*Pi..2*Pi,legend=f1,color=re
d):
> b1:=
plot((sin(x+Pi/2)/2)+1,x=-2*Pi..2*Pi,legend=f2,color=gr
een):
> c1:=
plot((sin(x+Pi)/2)+1,x=-2*Pi..2*Pi,legend=f3,color=blue
):
> display({a1,b1,c1});
7
Para mas informacin acerca de la comparacin entre grficas vea el Anexo de
Funciones.
Ahora usted est en condiciones de realizar la parte 1 de la prctica de funciones.
Crecimiento, concavidad, intervalos de positividad y negatividad
Cargando la librera Calculus1 para estudiantes, es posible utilizar el comando
FuntionChart.
Este comando tiene como parmetros
el intervalo a graficar, por omisin se asume el intervalo [-10,10]
la concavidad, por omisin se muestra rellenada de amarillo y verde, con
flechas que indican la direccin de la concavidad.
el singo de la funcin, si se omite este parmetro no se muestra el signo
el crecimiento, por omisin se muestra la lnea en rojo en los intervalos de
crecimiento y en azul en los
intervalos de decrecimiento.
En primer lugar es necesario cargar la librera mencionada:
> with(Student[Calculus1]):
Ahora se ver un ejemplo sin parmetros:
> f(x):= (x^3 - 4*x^2 - 50*x + 12)/(x^2 - x - 17);
> FunctionChart(f(x));
Agregando los pmetros mencionados se tiene:
> FunctionChart(sin(x)+x/2,x=-4..4,slope=color(blue,magenta)
,concavity=arrow);
> FunctionChart(sin(x)+x/2,x=-4..4,concavity=arrow,sign=[col
or(red,yellow),filled(coral, wheat)]);
Representacin grfica de funciones dadas en forma paramtrica
Para el inicio, se debe ejecutar:
> restart:
> with(plots):
> with(plottools):
El siguiente ejemplo muestra como ingresar una funcin dada en forma paramtrica:
= ( ) x t 3 ( ) sin t
3
= ( ) y t 3 ( ) cos t
3
> fp:=[3*sin(t)^2,3*cos(t)^2];
8
Para hacer el grfico se le indica al programa la funcin y el intervalo del parmetro:
> plot(fp,t=0..Pi);
Otra forma para generar hacer el grfico de una funcin paramtrica es:
> plot( [(t^2-1)/(t^2+1),2*t/(t^2+1), t=-infinity..infinity]
);
Puede graficar ahora las funciones de la pgina 20 del Mdulo 2
Representacin grfica de funciones en coordenadas polares
El comando para resolver grficos de funciones dadas en coordenadas polares es polarplot,
al cual se le indica como primer argumento el radio en funcin de t, luego el ngulo como
funcin de t y los intervalos horizontales y verticales.
Si se le indica una sola expresin, esta se entiende como el radio en funcin del ngulo.
El resto de las posibles opciones son las mismas que para el comando plot:
> restart;
> with(plots):
> polarplot([cos(t),sin(t),t=0..4*Pi],color=gold);
Para indicar a Maple que los parmetros representan coordenadas polares se agrega la
opcin como argumento del comando, despus de los intervalos:
> plot([x^2,x,x=0..3*Pi],-8..8,0..6,coords=polar);
> with(plots):polarplot(1): # esta ltima sentencia indica
nivel de usuario
polarplot([cos(t),sin(t),t=0..4*Pi],color=gold);
polarplot({t,[2*cos(t),sin(t),t=-Pi..Pi]},t=-Pi..Pi,numpoi
nts=50);
S := t->100/(100+(t-Pi/2)^8): R :=
t->S(t)*(2-sin(7*t)-cos(30*t)/2):
polarplot([R,t->t,-Pi/2..3/2*Pi],numpoints=2000,axes=NONE)
;
Representacin grfica de funciones implcitas
Para el inicio, debemos ejecutar:
> restart:
> with(plots):
> with(plottools):
9
Estas representaciones se ejecutan a travs de la funcin implicitplot, asignndole como
argumentos la expresin que relaciona las variables y los intervalos de variacin de las
mismas:
> with(plots):
implicitplot(x^2+y^2=1,x=-1..1,y=-1..1);
Una relacin en coordenadas polares, tambin puede ser graficada con esta funcin
agregando la opcin correspondiente:
> implicitplot(r=1-cos(theta),r=0..2,theta=0..2*Pi,coords=po
lar);
Ahora usted est en condiciones de realizar la parte 2 de la prctica de funciones
Puede representar las funcioness de las pginas 26,27,28,35 y 36 del Mdulo 2
Lmite de Funciones
Introduccin
Sea la funcin f(x) =
x
2
16
x 4
que no existe en el punto x = 4, si se intenta evaluarla se
obtiene un error :
> f(x):= (x^2-16)/(x-4);
> eval(f(x),x=4);
Construyendo la siguiente tabla de valores y evaluando la funcin en las ocurrencias
obtenidas, resulta:
> T:= [seq(evalf(4-10^(-n)),n=1..5)];
> f(T):= seq(eval(f(x),x=i),i=T);
Se observa que los valores de la funcin tienden al lmite 8 cuanto el valor de la variable se
aproxima a 4. Obteniendo la expresin de la funcin simplificada, se justifica el valor
anterior:
> simplify(f(x));
Clculo de lmites
Dada un funcin f(x) para calcular el valor del lmite cuando x tiende al punto a, se usa el
operador limit indicndole como parmetro el punto a:
> f(x):= (x^2-16)/(x-4);
10
> limit(f(x),x=4);
> limit(sin(2*x)/x,x=0);
> limit(exp(x),x=-infinity);
> limit(exp(x),x=infinity);
> limit(ln(x),x=0);
En el caso en que el lmite no existe, pero los valores de la funcin permanecen acotados,
el programa da por resultado las cotas de la funcin:
> limit(sin(x),x=infinity);
> limit(cos(x),x=-infinity);
En el caso en que el lmite no existe y los valores de la funcin no estn acotados, no se
obtiene ningn resultado:
> limit(1/x,x=0);
Lmites laterales
Para calcular limites laterales se agrega la opcin como parmetro dentro del operdor limit:
> limit(1/x,x=0,left);
> limit(1/x,x=0,right);
A continuacin se da un ejemplo de lmites laterales para una funcin definida por partes:
> f(x):= piecewise (x<1,x,x>=1,x^2);
> limit(f(x),x=1,left);limit(f(x),x=1,right);
Ahora puede hacer los ejercicios de las pginas 16, 17, 18 y 19 del Mdulo 3.
Aritmtica de lmites
Para obtener una descripcin de la aritmtica de lmites, se puede cargar la librera
Calculus1 para estudiantes, y utilizar el comando Rule, estas reglas no se aplican a formas
indeterminadas. A continuacin se decriben las reglas para el producto por escalar, y el
producto, suma y cociente de funciones:
> with(Student[Calculus1]):
> Rule[`c*`](Limit(4*cos(x), x=0, right));
> Rule[`*`](Limit(x*cos(x)*ln(x), x=0, right));
> Rule[`+`](Limit(x+cos(x)+ln(x), x=0, right));
> Rule[`/`](Limit(x/cos(x), x=0, right));
Hay otras reglas que requieren parmetros como es la regla de sutitucin, se ejecuta a
travs del comando change y lleva como parmetro la definicin de la nueva variable :
11
> Rule[change, u=1/x](Limit(x*sin(1/x), x=infinity, left));
Asntotas
Para hallar las asntotas de un funcin f(x) es necesario cargar la librera Calculus1 para
estudiantes, y utilizar el comando Asymptotes:
> with(Student[Calculus1]):
> f(x):=1/(x - 3) + 2*x;
> Asymptotes( f(x), x );
Si se desea obtener las asntotas slo en un intervalo definido, hay que agregarlo como una
opcin en el comando:
> Asymptotes( 1/(x - 3) + 2*x, x = 0..2 );
> Asymptotes( tan(x), 0..10 );
Para que el programa de por resultado el valor numrico, se debe pedir esta opcin de la
siguiente forma:
> Asymptotes( tan(x), 0..10, numeric );
Ahora puede hacer los ejercicios de la pgina 21 del Mdulo 3.
Continuidad
Maple tiene el comando iscont, que simplemente devuelve verdadero o falso, dependiendo
de si la funcin es contnua o no en el intervalo que se indica:
> iscont( 1/x, x=1..2 );
> iscont( 1/x, x=-1..1 );
> iscont( 1/x, x=0..1 );
> iscont( 1/x, x=0..1, 'closed' );
> iscont( 1/x, x = -infinity..infinity);
El comando discont devuelve el conjunto de valores donde la funcin es discontnua:
> discont(1/x, x);
> discont(tan(x), x);
En la expresin precedente el smbolo _Z indica "los mltiplos enteros", el nmero natural
que lo acompaa indica el orden del smbolo dentro de la hoja de trabajo. As, si se
obtienen 20 resultados distintos que involucren mltiplos enteros, el ltimo resultado
contendr el smbolo _Z20.
Como ejemplo puede ejecutarse la siguinte lnea de comandos, donde el programa debe
12
calcular 9 distintos intervalos de discontinuidad, para comenzar se ejecuta el comando restart
y as borrar los valores eventualmente cargados:
> restart:
> discont(1/sin(x),x);discont(1/sin(2*x),x);discont(1/sin(3*
x),x);discont(1/sin(4*x),x);discont(1/sin(5*x),x);discont(
1/sin(6*x),x);discont(1/sin(7*x),x);discont(1/sin(8*x),x);
discont(1/sin(9*x),x);
Ahora usted puede resolver los ejercicios de la pgina 29 del Mdulo 3.
Sucesiones
Definir una sucesin es definir una funcin, para obtener el desarrollo de los primeros trminos
de una sucesin se utiliza el comando $ con un parmetro que indica el rango de aplicacin de
la funcin que la define. Como ejemplo se define una sucesin y se hallan los primeros
trminos de la misma:
> s(n):=1/n;
> s(n) $ n=1..5;
> (-1)^n/3*n $ n=1..10;
Para hallar el lmete de la sucesin, se utiliza el operador limit ya visto:

> limit(s(n),n=infinity);
Series
Para cargar una serie simplemente se ingresa la expresin que la define con el comando sum.
Se puede calcular algunos trminos de la sucesin de sumas parciales, indicndole al comando
sum, adems del trmino general de la serie, los lmites de la suma. Los parmetros se deben
ingresar entre comillas simples. En el ejemplo siguiente se antepone el comando evalf[5], para
obteber los resultados numricos expresados con 5 dgitos:
> evalf[5](sum('n^(3/2)','n'=1..10));evalf[5](sum('n^(3/2)','n'
=1..100));evalf[5](sum('n^(3/2)','n'=1..105));evalf[5](sum('n
^(3/2)','n'=1..110));evalf[5](sum('n^(3/2)','n'=1..200));
El comando sum tambin efecta la suma infinita que representa la serie:
> Sum('n^(3/2)','n'=1..infinity)=sum('n^(3/2)','n'=1..infinity)
;
Otra forma de calcular la suma de una expresin es definirla previamente, y luego calcular su
suma:
13
> an:=1/(n^2);
> Sum(an,'n'=1..infinity)=sum(an,'n'=1..infinity);
Se puede verificar la condicin necesaria de convergencia evaluando el correspondiente lmite:
> limit(an,n=infinity);
Derivadas
Clculo de derivadas
Para calcular la derivada de una funcin f(x) respecto de la variable x se utiliza el comando
diff, al que se le dan como parmetros la funcin y la variable, as:
> diff(sin(x),x);
> diff(x*sin(cos(x)),x);
Nota: sobre cualquier expresin de resultado se puede seleccionar, con el botn derecho del
mouse, la opcin Differentiate y luego el nombre de la variable, y se obtendr la
correspondiente derivada.
El resultado del comando diff, no es una funcin, sino tan slo una expresin algebraica.
Para transformarlo en una funcin es necesario aplicarle el operador unapply, indicndole el
nombre de la variable independiente:
> unapply(%,x);
Recordando que los comando en mayscula indican la operacin sin obtener su resultado,
se puede ejecutar la siguiente sentencia:
> Diff(tan(x),x) = diff(tan(x),x);
La obtencin de las derivadas sucesivas se puede indicar de tres formas distintas:
> Diff(Diff(x^5,x),x) = diff(diff(x^5,x),x); #1)la
aplicacin reiterada
de la derivada
> diff(x^5,x); #2) se calcula la derivada primera
> diff(%,x); # y luego la derivada segunda
> diff(x^5,x$2); #3) se agrega el smbolo $ seguido de la
cantidad de veces
a derivar.
Operador de derivacin
El operador D da por resultado la derivada de una funcin dada , por ejemplo:
14
> restart:
> D(ln);
> D(sec);
> D(cos)(x);
> g:= x->piecewise(x > 0,-2,3 - x);
> D(g);
Con este operador es posible obtener la aritmtica de derivadas:
> D(f@g); # La derivada de la composicin de dos funciones
> D(f+g-h); # La derivada de la suma/resta de funciones
> D(f*g); # La derivada de la multiplicacin de funciones
> D(f/g); # La derivada de la divisin de funciones
Derivada de la funcin implcita
Para evaluar la derivada de la funcin implcita el comando es implicitdiff, al que hay que
indicarle como primer parmetro la variable dependiente y como segundo la
independiente:
> f := x^2+y^3=1;
> implicitdiff(f,y,x); # el resultado obtenido en este caso
es y'
> implicitdiff(f,x,y); # el resultado obtenido en este caso
es x'
Reglas de derivacin
Para obtener las reglas de derivacin aplicadas en el clculo, es necesario cargar la librera
Calculus1 para estudiantes, y utilizar el comando Rule. A continuacin se describen las
reglas que se pueden invocar para ver el desarrollo de derivas:
Regla Nombre Abreviado Descripcin
chain (f(g(x)))' = f'(g(x))*g'(x)
constant c' = 0
constantmultiple `c*` (c*f)' = c*f'
difference `-` (f-g)' = f'-g'
identity `^` x' = 1
power `^` (x^n)' = n*x^(n-1)
product `*` (f*g)' = f'*g + f*g'
quotient `/` (f/g)' = (g*f' - f'g')/g^2
sum `+` (f+g)' = f'+g'
Veamos algunos ejemplos:
15
> with(Student:-Calculus1):
infolevel[Calculus1] := 1: # (el valor 1 indica que slo
se requiere informacin para
usuarios finales)
> Rule[`*`](Diff(x^2*sin(x^2), x)); # aplicacin de la
derivada del producto
Es necesario escribir explcitamente el sen(x^2) como la composicin de funciones, para
depus poder evaluar la derivada de la funcin compuesta. En el siguiente resultado la
expresin X_ representa a la funcin h(x) = x^2 :

> Rule[chain](%); # aplicacin de la regla de la cadena
> Rule[sin](%); #aplicacin de la derivada del seno
> Rule[power](%); #aplicacin de la derivada de la potencia
> Rule[power](%); #aplicacin de la derivada de la potencia
Derivada de la funcin dada en forma paramtrica
Para calcular la derivada de una funcin dada en forma paramtrica, se cargan cada una de
las funciones coordenadas y se calculan los correspondientes derivadas:
> x(t):=3*sin(t);y(t):=5*cos(t);
> f_prima := diff(y(t),t)/diff(x(t),t);
Para calcular la derivada segunda, se debe calcular el determinante de la matriz formada
por las derivadas primeras y segundas. En primer lugar definimos la matriz, utilizando la
ayuda del men View/Palettes/Matrix palettes:
> A:=<<diff(x(t),t) | diff(y(t),t)> , <diff(x(t),t$2) |
diff(y(t),t$2)>>;
Luego calculamos la derivada segunda, resolviendo el cociente entre el determinante de A
y el cubo de la derivada primera de x respecto de t. Con el propsito de poder calcular el
determinante se debe cargar la librera de lgebra lineal:
> with(linalg):
> f_segunda := det(A)/diff(x(t),t)^3;
Ahora puede resolver los ejercicios de las pginas 24 y 25 del Mdulo 6.
Aplicaciones de la derivada
Recta Tantgente
Se ver el significado de recta trangente a una curva a travs de un grfico con animacin.
Ntese que una vez ejecutados los comando que se describen a continuacn, y
16
posicionndose sobre la zona del grfico resultante, aparece una nueva barra de menes
para controlar la animacin.
> restart: with(plots):
> f:=x->x^3-5*x^2+x+10;
La siguiente lnea define la recta tangente a la grfica de f en x = a:
> T := (x,a) -> f(a) + (x - a) * D(f)(a);
Si necesita aclaracin sobre algunos de los controles del nuevo men desplegado, haga click
aqu.
> display(plot(f(x),x=-2..5,y=-8..12,thickness=3,color=red),
animate(T(x,t),x=-2..5,t=-1..5,view=-8..12,color=blue,fram
es=60));
Del mismo modo la recta normal a la curva en cada punto a viene dada por:
> N := (x,a) -> f(a) + (x - a) * (-1)/D(f)(a);
Crecimiento, concavidad, puntos crticos
Ya se vi como visualizar a travs de una grfica el crecimiento, decrecimiento y concavidad
de una funcin.
Para determinar los intervalos basta con resolver las ecuaciones correspondientes:
> f(x):=2*x^3 + 5*x^2 - 4*x;
> solve(diff(f(x),x) < 0);solve(diff(f(x),x) >
0);solve(diff(f(x),x$2) < 0);solve(diff(f(x),x$2) > 0);
Cargando la librera Calculus1 para estudiantes, es posible utilizar los comandos
ExtremePoints (detallado mas arriba) e InflectionPoints, para hallar los puntos extremos y
los de inflexin. Este comando tiene como parmetro no obligatorio, el intervalo donde se
deben hallar los extremos:
> with(Student[Calculus1]):
> ExtremePoints(f(x));
> InflectionPoints(f(x));
Para graficar las caractersticas anteriores adems de los parmetros ya visto, se puede
agregar al comando FunctionChar, con la opcin pointoptions, que identifica los mximos,
mnimos, puntos de inflexin y ceros de la grfica de la funcin:
> FunctionChart(f(x),pointoptions=[symbolsize=20]);
Ahora puede resolver los ejercicios de la pgina 2,3,18 y 19 del Mdulo 7.
17
Frmula de Taylor
Para desarrollar en serie de Taylor una funcin o expresin en un punto determinado, el
programa tiene el comando taylor, al cual se le agregan dos parmetros, el punto en el cual
se desarrolla, y el grado del ltimo trmino (en caso de omisin de ste ltimo se calcula
hasta el grado 6) :
> f(x):= exp(x)*sin(x);
> taylor(f(x),x);taylor(f(x),x,10);
Para convertir el resultado obtenido en un polinomio se utiliza el comando convert, y luego
para convertir el polinomio en una funcin se usa el comando unapply:
> convert(%,polynom);
> f_t:=unapply(%,x);
Para tener una representacin grfica de las sucesivas aproximaciones, se pueden efectuar
las siguientes evaluaciones,
1) Calculamos el desarrollo de la funcin f en serie de Taylor hasta los grados 3, 5 y 8
2) Transformamos los resultados obtenidos en polinomios
3) Transformamos los polinomios en funciones
4) Graficamos la funcin y sus tres aproximaciones
5) Y finalmente mostramos todas las grficas en un mismo par de ejes
> restart:with(plots):with(plottools):
> f(x):= exp(x)*sin(x);
> t3:=taylor(f(x),x,3):t5:=taylor(f(x),x,5):t8:=taylor(f(x),
x,8):p3:=convert(t3,polynom):p5:=convert(t5,polynom):p8:=c
onvert(t8,polynom):f3:=unapply(p3,x);f5:=unapply(p5,x);f8:
=unapply(p8,x);
> plot([f(x),f3(x),f5(x),f8(x)],x=-Pi..Pi,y=-5..15,style=[li
ne,point,point,point],color=[black,red,blue,green]);
Ahora puede resolver los ejercicios de la pgina 15 del Mdulo 7.
Teorema del valor Medio
El comando MeanValueTheorem da por resultado un grfico de la funcin f en el intervalo
indicado, marcando el punto perteneciente al intervalo donde se verifica el Teorema del
valor Medio. A este comando es necesario darle como parmetros la funcin, la variable
independiente y el intervalo de aplicacin del teorema.
Se pueden agregar otros parmetros, como por ejemplo output indicndole a este parmetro
la opcin points, en lugar del grfico el comando da por resultado los valores donde se
verifica el teorema:
(Nota: posiciondose sobre el resultado y elegiendo del men contextual, la opcin
MapOnto/Aproximate/5, se obtienen los valores numricos de los puntos)
18
> with(Student[Calculus1]):
> MeanValueTheorem(sin(x),1..5,output=points);
> R0 := map(evalf[5],[Pi-arccos(-1/4*sin(5)+1/4*sin(1)),
Pi+arccos(-1/4*sin(5)+1/4*sin(1))]);
Ejecutando el mismo comando sin la opcin output, obtenemos el grfico:
> MeanValueTheorem(sin(x),1..5);
Regla de L'Hospital
Para la aplicacin de la regla de L'Hopital con el comando limit se antepone el comando Rule
, indicando como parmetro la regla y la funcin numerador:
> with(Student[Calculus1]):
> f(x):=(2^x-1)/x;
> Rule[lhopital,(2^x-1)](Limit(f(x),x=0,right));
> g(x):=sin(x)/(1-cos(x));
En el siguiente ejemplo se le pide al programa la aplicacin de la regla a un cociente de
funciones que no verifica las hiptesis del teorema, con lo cual la regla no se aplica:
> Rule[lhopital,sin(x)](Limit(g(x),x=Pi));
El siguiente es un ejemplo donde las funciones tienden a infinito:
> h(x):= ln(x)/(1/x);
> Rule[lhopital,ln(x)](Limit(h(x),x=0,right));
Ahora puede resolver la prctica de las pginas 22, 23 y 24 del mdulo 7.
Integral Indefinida
Primitiva
Para hallar la primitiva de una funcin dada se utiliza el comando int, al que se le indicar la
funcin integrando y la variable de integracin. En los siguientes ejemplos se defininen
cuatro funciones, y se obtienen las correspondientes primitivas:
(Nota: sobre cualquier expresin de resultado se puede seleccionar, con el botn derecho
del mouse, la opcin Integrate y luego el nombre de la variable, y se obtendr la
correspondiente primitiva.)
> f1(x):=sin(x);f2(x):=x^3+1/x-1/((x^2)+1);f3(x):=exp(x)-5;f
4(x):=3*sin(x)^2;f5(x):=x^3+ln(x)-arctan(x);
> int(f1(x),x);int(f2(x),x);int(f3(x),x);int(f4(x),x);int(f5
19
(x),x);
Con el objeto de visualizar el resultado con la indicacin del problema, usamos la
expresin del comando en maysculas.
> Int(f1(x),x)=int(f1(x),x); #ntese que la expresin
precedente no es una asignacin de valores, sino
simplemente una descripcin seguida de una operacin.
Ahora usted puede resolver los ejercicios de la pgina 4 del Mdulo 8.
Reglas de integracin
Para tener disponible las reglas de integracin se utiliza la librera de clculo para
estudiantes, y se aplica el comando Rule:
> with(Student:-Calculus1):
Como ejemplo se pueden ejecutar las siguientes sentencias, los resultados muestra la
aplicacin de la regla de integracin solicitada en cada caso. Los mtodos de integracin
por partes y por sustitucin se detallan mas abajo :
> Rule[`c*`](Int(3*sin(x),x));
> Rule[parts,sin(x),exp(x)](Int(sin(x)*exp(x),x));
> Rule[change,u=2*x](Int(sin(2*x), x=a..b));
Mtodo de sustitucin
Los diferentes mtodos de integracin se hallan en la librera de clculo para estudiantes:
> with(student):
Para resolver integrales por sustitucin hay que indicarle al programa, la sustitucin
deseada, la integral a resolver (con el comando Int en su forma inoperante) y el nombre de
la nueva variable de integracin. El comando a utilizar es changevar, as para resolver:
> Int((cos(x)+1)^3*sin(x), x);
debemos ingresar la siguiente sentencia:
> % = changevar(cos(x)+1=u,%,u);
O bien:
> Int(sqrt(1-x^2),x)=changevar(x=sin(u),Int(sqrt(1-x^2),x),u
);
20
Ahora usted puede resolver los ejercicios de la pgina 6, 8, 9 y 11 del Mdulo 8.
Integracin por partes
Los diferentes mtodos de integracin se hallan en la librera para estudiantes:
> with(student):
Para resolver integrales por partes se usa el comando intparts, hay que indicarle la funcin a
integrar considerada u* dv y cual de ellas es la funcin u. Como resultado se obtiene la
expresin u v d

v u
Como ejemplo:
> Int(x^k*ln(x),x)=intparts(Int(x^k*ln(x),x),ln(x));
resolviendo luego la segunda integral, se tiene:
> int(x^(k+1)/(x*(k+1)),x);
O simplemente:
> intparts(Int(sin(x)*x+sin(x), x), sin(x));
Ahora usted puede resolver los ejercicios de la pgina 6 del Mdulo 8.
Funciones racionales algebraicas
El mtodo de fracciones simples se encuentra en la librera para estudiantes:
> with(student):
Para aplicar el mecanismo de transformar una expresin racional fraccionaria, en una suma
de facciones simples, se utiliza el comando convert, al cual se le dan como parmetros la
expresin a transformar, la opcin parfrac, la variable independiente y la opcin real, para
indicar que las races deben buscarse en el cuerpo de los nmeros reales. Previamente el
programa simplificar la expresin. As, dada:
> f:= (x^5+1)/(x^4-x^2);
Se la descompone en una suma con la siguiente sentencia:
> convert(f,parfrac,x,real);
Ahora se integra la funcin cuya expresin es la anterior:
21
> Int(f,x)=int(%,x);
Tambin es posible indicar toda la operacin en una sola sentencia:
> Int((4*x^3-6*x^2-2)/(x^4-2*x^3-2*x+4),x)=int(convert((4*x^
3-6*x^2-2)/(x^4-2*x^3-2*x+4),parfrac,x),x);
Ahora usted puede resolver los ejercicios de la pgina 13, 14 y 15 del Mdulo 8.
Integral Definida
Sumas integrales inferiores y superiores
Con el objetivo de visualizar las sumas de Riemman se pueden ejecutar las siguentes
sentencia que tienen como argumentos: la funcin a integrar, el intervalo de integracin, la
indicacin de si se trata de sumas inferiores (left) o superiores (right), y en este caso la
indicacin animation para ver las sucesivas particiones del intervalo
(Una vez ejecutados los comando que se describe a continuacn, y posicionndose sobre la
zona del grfico resultante, aparece una nueva barra de menes, para controlar la
animacin.Si necesita aclaracin sobre algunos de los controles del nuevo men
desplegado, haga click aqu ).
> with(Student[Calculus1]):
> RiemannSum(ln(x),1..100,method=lower,output=animation);
> RiemannSum(ln(x),1..100,method=left,output=animation);
Regla de Barrow
Para calcular la integral definida, basta agregarle al comando int el intervalo de integracin
que se desea. El comando indicado controla las discontinuidades en el intervalo dado y, en
caso de ser posible, devuelve la integral definida como la suma de las integrales definidas
independientes. Como ejemplos se tienen:
> int(x^2,x=1..2);
> f(x):= piecewise (x<0,x,x>=0 and x<1,-2,x>=1,x^2+1);
> int(f(x),x=-1..2);
Ahora usted puede resolver los ejercicios de la pgina 7 y 8 del Mdulo 9.
Longitud de arco
El comado ArcLength(f(x),x=a..b) evala la longitud de arco de la expresin f(x) entre los
puntos a y b. Se le pueden agregar las opciones integral, para que de por resultado la
integral a evaluar:
> with(Student[Calculus1]):
22
> ArcLength(ln(x),x=1..4,output=integral);
> ArcLength(ln(x), x=1..4);
> evalf[5](%);
En caso que la funcin venga dada en forma paramtrica, se pueden evaluar las siguientes
entencias:
> r:=t->vector([3*cos(t),3*sin(t)]);
> sqrt(diff(3*cos(t),t)^2+diff(3*sin(t),t)^2);
> evalf[5](int(%,t=1..2));
Ahora usted puede resolver los ejercicios de la pgina 11 del Mdulo 9.
Volmenes y superficies de revolucin
Para resolver volmenes de revolucin, se utiliza el comando VolumeOfRevolution, al que
se le dan como parmetros la expresin para la que se desea hacer el clculo y el intervalo
de integracin. Se le pueden agregar los parmetros del tipo de respuesta deseado, y el eje
de rotacin (por omisin el programa asume el eje de abscisas):
> with(Student[Calculus1]):
> VolumeOfRevolution(sin(x)+1,x=0..3,output=integral);
> VolumeOfRevolution(sin(x)+1,x=2*Pi..3*Pi,output=integral,a
xis=vertical);
> evalf[5](VolumeOfRevolution(sin(x)+1,x=0..3));
> evalf[5](VolumeOfRevolution(sin(x)+1,x=0..3,axis=vertical)
);
Para resolver superficioes de revolucin, se utiliza el comando SurfaceOfRevolution, para
los parmetros valen las mismas aclaraciones que para volmenes de revolucin:
> SurfaceOfRevolution(x^2+1,x=0..1,output=integral);
> SurfaceOfRevolution(x^2+1,x=0..1);
> evalf[5](%);
> SurfaceOfRevolution(x^2+1,x=0..1,axis=vertical,output=inte
gral);
> evalf[5](SurfaceOfRevolution(x^2+1,x=0..1,axis=vertical));
Ahora usted puede resolver los ejercicios de la pgina 14 y 15 del Mdulo 9.
Integrales generalizadas
Para resolver este tipo de integrales, el programa calcula el lmite implcito para la
solucin del problema:
> int(exp(-x^2)*ln(x)^2,x=0..infinity);
23
> evalf[15](%);
> int(exp(-x),x=0..infinity);
> int(1/x,x=1..infinity);
En el caso que la integral es oscilante, el resultado de la sentencia es indefinido, en el
sigiuente ejemplo se ve el rango de oscilacin, calculando el lmite:
> int(sin(x),x=1..infinity);limit(1-cos(t),t=infinity);
24