UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERÍA Y ARQUITECTURA

ESCUELA DE INGENIERÍA ELÉCTRICA
ANÁLISIS ELÉCTRICO I
CICLO I - 2018

Catedrático: Ing. Gerardo Marvin Jorge Hernández.

Instructores: Br. Karen Amanda Agreda Rivas.
Br. Aura Lucia Mendoza Merlos.

Guía de Simulación III: Circuitos de Segundo Orden.

Se resolverán circuitos que contengan inductores y capacitores, acompañados de resistencias,

que produzcan una respuesta de segundo orden diferencial. Se tratarán, circuitos RLC que
posean o no fuente de excitación externa para un tiempo 𝑡 > 0 s y circuitos con
amplificadores operacionales.

Ejemplo 1. Determinar 𝑣(𝑡) para 𝑡 > 0 para los siguientes tres valores de R: 1.923 Ω, 5 Ω y
6.25 Ω; considerando que 𝑣(0) = 5 𝑉, 𝑖(0) = 0. Este es un circuito RLC paralelo sin fuente
de excitación.

Código en SPICE OPUS:

* Ejemplo 1.
* Guía de Simulación III.
* AEL115 Ciclo I-2017.

* Resistencias.
R 1 0 1.923Ohm
* Inductores.
L 1 0 1H IC = 0A
* Capacitores.
C 1 0 10mF IC = 5V
.control
destroy all
* Análisis Transitorio 1.
tran 100us 1.5s 0us 10us uic
* Análisis Transitorio 2.
alter r=5Ohm
tran 100us 1.5s 0us 10us uic
* Análisis Transitorio 3.
alter r=6.25Ohm
tran 100us 1.5s 0us 10us uic
plot tran1.V(1) tran2.V(1) tran3.V(1)
+ xlabel 'Tiempo [s]' ylabel 'Tensión [V]'
+ title 'Vo(t) para R = 1.925 Ohm [roja]
+ R = 5 Ohm [verde]
+ R = 6.25 Ohm'
destroy all
.endc
.end

Ejemplo 2. En el circuito mostrado, determinar 𝑣(𝑡) e 𝑖(𝑡) para 𝑡 > 0 para los siguientes tres
valores de R: 5 Ω, 4 Ω y 1 Ω. Este es un circuito RLC serie con fuente de excitación.
Código en SPICE OPUS:

* Ejemplo 2.
* Guía de Simulación III.
* AEL115 Ciclo I-2017.

* Fuentes de tensión independientes.

Vs 1 0 24V
Vx 2 3 0V
* Para simular la apertura del interruptor en t = 0 s.
Vcontrol 6 0 DC 0V AC 0V 0deg PULSE ( 1V 0V 0s 0s 0s 8s 8s )
* Resistencias.
R 1 2 5Ohm
R1 5 0 1Ohm
* Inductores.
L 3 4 1H
* Capacitores.
C 4 0 0.25
* Interruptores.
S1 4 5 6 0 Switch
.model Switch SW ( VT=0.1V VH=0V RON=0.0001Ohm ROFF=10e5Ohm )
.control
destroy all
* Análisis Transitorio 1.
tran 10ms 8s 0us 1ms
* Análisis Transitorio 2.
alter r=4Ohm
tran 10ms 8s 0us 1ms
* Análisis Transitorio 3.
alter r=1Ohm
tran 10ms 8s 0us 1ms
plot tran1.V(4) tran2.V(4) tran3.V(4)
+ xlabel 'Tiempo [s]' ylabel 'Tensión [V]'
+ title 'V(t) para R = 5 Ohm [roja]
+ R = 4 Ohm [verde]
+ R = 1 Ohm'
plot tran1.i(Vx) tran2.i(Vx) tran3.i(Vx)
+ xlabel 'Tiempo [s]' ylabel 'Corriente [A]'
+ title 'i(t) para R = 5 Ohm [roja]
+ R = 4 Ohm [verde]
+ R = 1 Ohm'
destroy all
.endc
.end

Resultado para 𝑣(𝑡):

Resultado para 𝑖(𝑡):

Ejemplo 3. Determinar la respuesta completa 𝑣𝑜 (𝑡) del siguiente circuito para 𝑣𝑠 (𝑡) =
20𝑒 −9𝑡 𝑢(𝑡).
Código en SPICE OPUS:

* Ejemplo 3.
* Guía de Simulación III.
* AEL115 Ciclo I-2017.

* Fuente de tensión exponencial.

Vs 1 0 DC 0V AC 0V 0deg EXP ( 0V 20V 0s 0.1ns 0s 111.111ms )
* Resistencias.
R1 1 2 1Ohm
R2 2 3 1Ohm
* Capacitores.
C1 3 0 1
C2 2 4 1
* Amplificadores Operacionales.
E1 4 0 3 4 1Meg
.control
* Análisis Transitorio.
tran 100us 8s 0us 10us
plot V(4) xlabel 'Tiempo [s]' ylabel 'Tensión [V]'
+ title 'Respuesta completa vo(t)'
destroy all
.endc
.end