finish

/clear
/FILNAME,buckl,DB
/cwd,d:\buckl
!/TITLE,Buckling analysis of composite shell
/PREP7
CSYS,WP
*afun,deg
/graphics,power
/GFORMAT,f,,2
/PLOPTS,DATE,0
/udoc,,cntr,right
pitch=4.5 !degrees
!circm offset of long ribs
offset=101.6 !mm
!longt offset of cir ribs
cylen=12000
shelod=2600
shelthk=6.35
ribht=10
ribht=ribht+shelthk/2 !at mean rad surface
ribthk=5
althk=3
mrad=shelod/2-shelthk
shelid=shelod-2*shelthk
ang=90
pvalue=.1
axP=shelod*pvalue/(4*shelthk)
!
k,1,0
!CENTER
k,2,0,0,-cylen
!Z AXIS OF ROTATION
CYL4, 0, 0, mrad, 0, mrad-ribht, ang,0
lsel,s,loc,y,0
lsel,r,loc,x,0,mrad
l,1,2
!guideline for long stiffner
last=_return
adrag,all,,,,,,last
agen,cylen/offset+1,1,,,0,,-offset !array for cir ribs
!creation of long ribs
csys,wp
wpcsys,,1
agen,ang/pitch+1,2,,,0,pitch
!creation of cirf ribs
lsel,s,radius,,mrad
lsel,r,loc,z,0
adrag,all,,,,,,last
lsel,s,radius,,mrad-ribht
lsel,r,loc,z,0
adrag,all,,,,,,last
allsel
aptn,all

nummrg,all
numcmp,all
MP,EX,1,2e5
MP,NUXY,1,0.3
MP,EX,2,0.71e5
MP,NUXY,2,0.3
ET,1,181
sectype,1,shell
secdata,shelthk
sectype,2,shell
secdata,ribthk
sectype,3,shell
secdata,althk
lsel,s,loc,x,mrad
asll,s,1
aatt,1,,1,,1
asel,inve
aatt,2,,1,,2
lsel,s,loc,x,mrad-ribht
asll,s,1
aatt,2,,1,,3
allsel
Esize,30
aclear,all
mshkey,1
amesh,all
csys,1
lsel,s,loc,z,0
lsel,r,loc,x,mrad
lsel,r,radius,,mrad
nsll,s,
nrotat,all
d,all,uy,0,,,,,uz,
csys,0
nsel,s,loc,y,0
CSYS,1
NSEL,R,LOC,X,MRAD
d,all,uy,0,,,,rotx,rotz
csys,0
nsel,s,loc,x,0
CSYS,1
NSEL,R,LOC,X,MRAD
d,all,ux,0,,,,roty,rotz
csys,1
lsel,s,loc,x,mrad
asll,s,1
sfa,all,,pres,pvalue

csys,1
ksel,s,loc,z,-cylen
kSEL,R,LOC,X,MRAD
lslk,s,1
sfl,all,pres,axP
nsll,s,
nrotat,all
d,all,uy,0,,,,,
allsel
/solu
sbctran,all
antype,0
solve
FINISH
!*****************SWITCH ON THE BUCKLING MODE
/SOLU
ANTYPE,BUCKLE
BUCOPT,LANB,1
MXPAND,1
SOLVE
FINISH
SAVE,SOLUTION,DB
/POST1 ! Enter post-processor
SET,FIRST
PLDISP ! Plots the deflected shape
finish