_SECTION_BEGIN( "Chart Setting" );

SetChartOptions( 0, chartShowArrows | chartShowDates | chartWrapTitle );

pxwidth = Status("pxwidth");
pxheight = Status("pxheight");

ColorBG= ParamColor( "Color Background", colorDefault );

SetChartBkColor( ColorBG );
_SECTION_END();

_SECTION_BEGIN( "CandleStick" );
SetChartOptions(0,chartShowArrows|chartShowDates);
Color_CandleUP = ParamColor("Candle UP" , ColorRGB(076,175,080));
Color_CandleDN = ParamColor("Candle DOWN", ColorRGB(244,067,054));
Color_CandleDJ = ParamColor("Candle Doji", colorBlack);
SetBarFillColor( IIf( Close > Open, Color_CandleUP, IIf ( Close < Open, Color_CandleDN, Color_CandleDJ )));
_N(Title = StrFormat("{{NAME}} - {{INTERVAL}} {{DATE}} \nOpen = %g, High = %g, Low = %g, Close = %g, Change = %.1f%% \n{{VALUES}}", O, H, L,
C, SelectedValue( ROC( C, 1 ) ) ));
Plot( C, "Close", ParamColor("Color Candle", colorDefault ), styleNoTitle | ParamStyle("Style Candle") | GetPriceStyle() );
_SECTION_END();

_SECTION_BEGIN( "Alligator" );
ShowAlligator = ParamToggle( "Show Alligator?", "No|Yes", 1 );
Lips_Period = 5;
Teeth_Period = 8;
Jaw_Period = 13;
MidPrice = ( H + L ) / 2;

Lips = MA( MidPrice, Lips_Period );

Teeth = MA( MidPrice, Teeth_Period );
Jaw = MA( MidPrice, Jaw_Period );

for ( i = Lips_Period + 1; i < BarCount; i++ )

{
iSum = ( Lips[i-1] * ( Lips_Period - 1 ) ) + MidPrice[i];
Lips[i] = iSum / Lips_Period;
}

for ( j = Teeth_Period + 1; j < BarCount; j++ )

{
jSum = ( Teeth[j-1] * ( Teeth_Period - 1 ) ) + MidPrice[j];
Teeth[j] = jSum / Teeth_Period;
}

for ( k = Jaw_Period + 1; k < BarCount; k++ )

{
kSum = ( Jaw[k-1] * ( Jaw_Period - 1 ) ) + MidPrice[k];
Jaw[k] = kSum / Jaw_Period;
}

GatorAbove0 = abs( Jaw - Teeth );

GatorBelow0 = -( abs( Teeth - Lips ) );
_SECTION_END();

_SECTION_BEGIN( "AO AND AC" );

AOFast = MA( MidPrice, 5 );
AOSlow = MA( MidPrice, 34 );
AO = AOFast - AOSlow;
AC = AO - MA( AO, 5 );
AOUB = AO > Ref( AO, -1 );
AODB = AO < Ref( AO, -1 );
ACUB = AC > Ref( AC, -1 );
ACDB = AC < Ref( AC, -1 );
GrnBar = AOUB AND ACUB;
RedBar = AODB AND ACDB;
_SECTION_END();

_SECTION_BEGIN( "Fractals" );
fUpA =
( Ref( H, -2 ) > Ref( H, -4 ) ) AND
( Ref( H, -2 ) > Ref( H, -3 ) ) AND
( Ref( H, -2 ) > Ref( H, -1 ) ) AND
( Ref( H, -2 ) > H );

fUpB =
( Ref( H, -2 ) > Ref( H, -5 ) ) AND
( Ref( H, -2 ) > Ref( H, -4 ) ) AND
( Ref( H, -2 ) == Ref( H, -3 ) ) AND
( Ref( H, -2 ) > Ref( H, -1 ) ) AND
( Ref( H, -2 ) > H );

fUpC =
( Ref( H, -2 ) > Ref( H, -6 ) ) AND
( Ref( H, -2 ) > Ref( H, -5 ) ) AND
( Ref( H, -2 ) == Ref( H, -4 ) ) AND
( Ref( H, -2 ) == Ref( H, -3 ) ) AND
( Ref( H, -2 ) > Ref( H, -1 ) ) AND
( Ref( H, -2 ) > H );

fUpD =
( Ref( H, -2 ) > Ref( H, -6 ) ) AND
( Ref( H, -2 ) > Ref( H, -5 ) ) AND
( Ref( H, -2 ) == Ref( H, -4 ) ) AND
( Ref( H, -2 ) > Ref( H, -3 ) ) AND
( Ref( H, -2 ) > Ref( H, -1 ) ) AND
( Ref( H, -2 ) > H );

fUpE =
( Ref( H, -2 ) > Ref( H, -8 ) ) AND
( Ref( H, -2 ) > Ref( H, -7 ) ) AND
( Ref( H, -2 ) == Ref( H, -6 ) ) AND
( Ref( H, -2 ) > Ref( H, -5 ) ) AND
( Ref( H, -2 ) == Ref( H, -4 ) ) AND
( Ref( H, -2 ) > Ref( H, -3 ) ) AND
( Ref( H, -2 ) > Ref( H, -1 ) ) AND
( Ref( H, -2 ) > H );

fDnA =
( Ref( L, -2 ) < Ref( L, -4 ) ) AND
( Ref( L, -2 ) < Ref( L, -3 ) ) AND
( Ref( L, -2 ) < Ref( L, -1 ) ) AND
( Ref( L, -2 ) < L );

fDnB =
( Ref( L, -2 ) < Ref( L, -5 ) ) AND
( Ref( L, -2 ) < Ref( L, -4 ) ) AND
( Ref( L, -2 ) == Ref( L, -3 ) ) AND
( Ref( L, -2 ) < Ref( L, -1 ) ) AND
( Ref( L, -2 ) < L );

fDnC =
( Ref( L, -2 ) < Ref( L, -6 ) ) AND
( Ref( L, -2 ) < Ref( L, -5 ) ) AND
( Ref( L, -2 ) == Ref( L, -4 ) ) AND
( Ref( L, -2 ) == Ref( L, -3 ) ) AND
( Ref( L, -2 ) < Ref( L, -1 ) ) AND
( Ref( L, -2 ) < L );

fDnD =
( Ref( L, -2 ) < Ref( L, -6 ) ) AND
( Ref( L, -2 ) < Ref( L, -5 ) ) AND
( Ref( L, -2 ) == Ref( L, -4 ) ) AND
( Ref( L, -2 ) < Ref( L, -3 ) ) AND
( Ref( L, -2 ) < Ref( L, -1 ) ) AND
( Ref( L, -2 ) < L );
fDnE =
( Ref( L, -2 ) < Ref( L, -8 ) ) AND
( Ref( L, -2 ) < Ref( L, -7 ) ) AND
( Ref( L, -2 ) == Ref( L, -6 ) ) AND
( Ref( L, -2 ) < Ref( L, -5 ) ) AND
( Ref( L, -2 ) == Ref( L, -4 ) ) AND
( Ref( L, -2 ) < Ref( L, -3 ) ) AND
( Ref( L, -2 ) < Ref( L, -1 ) ) AND
( Ref( L, -2 ) < L );

var1 = ValueWhen( fUpE OR fUpD OR fUpC OR fUpB OR fUpA, Ref( H, -2 ), 1 );

var2 = ValueWhen( fDnE OR fDnD OR fDnC OR fDnB OR fDnA, Ref( L, -2 ), 1 );
FracUp = HighestSince( var1 > 0, var1, 1 );
FracDn = LowestSince ( var2 > 0, var2, 1 );
_SECTION_END();

_SECTION_BEGIN( "WiseMan" );
WM1L = L < Ref( L, -1 ) AND C > ( ( H + L ) / 2 ) AND AODB AND AO < 0 AND ( O < Ref( Teeth, -5 ) AND C < Ref( Teeth, -5 ) ) AND ( L < Ref( Teeth, -
5 ) AND H < Ref( Teeth, -5 ) );
WM1S = H > Ref( H, -1 ) AND C < ( ( H + L ) / 2 ) AND AOUB AND AO > 0 AND ( O > Ref( Teeth, -5 ) AND C > Ref( Teeth, -5 ) ) AND ( L > Ref( Teeth,
-5 ) AND H > Ref( Teeth, -5 ) );
WM2L = Ref( AODB, -3 ) AND Ref( AOUB, -2 ) AND Ref( AOUB, -1 ) AND AOUB;
WM2S = Ref( AOUB, -3 ) AND Ref( AODB, -2 ) AND Ref( AODB, -1 ) AND AODB;
WM3L = Cross( C, FracUp );
WM3S = Cross( FracDn, C );
_SECTION_END();

_SECTION_BEGIN( "Extra" );
if( ShowAlligator )
{
PlotOHLC( Lips, Lips, Lips, Lips, "Lips", ParamColor( "Color Lips", colorGreen ), styleCloud | styleNoLabel, Null, Null, 3, -2 );
PlotOHLC( Teeth, Teeth, Teeth, Teeth, "Teeth", ParamColor( "Color Teeth", colorRed ), styleCloud | styleNoLabel, Null, Null, 5, -2 );
PlotOHLC( Jaw, Jaw, Jaw, Jaw, "Jaw", ParamColor( "Color Jaw", colorBlue ), styleCloud | styleNoLabel, Null, Null, 8, -2 );
Plot( FracUp, "F+", ParamColor( "Color F+", colorViolet ), ParamStyle( "Style F+", styleLine | styleDashed | stylenorescale ) );
Plot( FracDn, "F-", ParamColor( "Color F-", colorGrey40 ), ParamStyle( "Style F-", styleLine | styleDashed | stylenorescale ) );
PlotShapes( IIf( WM2L AND WM3L, shapeDigit4, IIf( WM1L, shapeDigit1, IIf( WM2L, shapeDigit2, IIf( WM3L, shapeDigit3, 0 ) ) ) ), colorGreen, 0,
L, -10 );
PlotShapes( IIf( WM2S AND WM3S, shapeDigit4, IIf( WM1S, shapeDigit1, IIf( WM2S, shapeDigit2, IIf( WM3S, shapeDigit3, 0 ) ) ) ), colorRed, 0,
H, 10 );
Plot( 3, "", IIf( GrnBar, colorGreen, IIf( AOUB AND ACDB, colorGrey40, IIf( AODB AND ACUB, colorGrey50, IIf( RedBar, colorRed,
colorViolet ) ) ) ), styleNoTitle | styleOwnScale | styleArea | styleNoLabel );
}
_SECTION_END();

_SECTION_BEGIN( "Re-Scale" );
Rescale = Param( "Rescale", 10, 1, 100, 1 );
Plot( HighestVisibleValue(H) + 10/100*((HighestVisibleValue(H) - LowestVisibleValue(L)) ), "OnlyReScale", colorBlack , styleLine|styleNoDraw|
styleNoTitle, Null, Null, 0, 1 );
Plot( LowestVisibleValue (L) - 10/100*((HighestVisibleValue(H) - LowestVisibleValue(L)) ), "OnlyReScale", colorBlack , styleLine|styleNoDraw|
styleNoTitle, Null, Null, 0, 1 );
_SECTION_END();

Title = Title + "\n\nJasa Utama Capital Sekuritas (cab. Daan Mogot) \nSuginta Ramli (0811116158) t.me/suginta"
+ "\nCentro City Residence Unit Office CG.02-06"
+ "\njuc.dmogot@gmail.com";