The Baxendall Tone Control

Dinesh Sharma
Electrical Engineering Department
I.I.T. Bombay
Mumbai 400 076

The Baxendall tone control is an interesting circuit. It divides the audio range in
three frequency ranges: low (known as bass), mid, and high (known as treble). The
objective of the circuit is to amplify or attenuate the bass or treble signals as desired
while leaving the mid-frequency signals unaffected.

To understand its operation, let us first look at the basic gain circuit given below.
In R1 Rv R2
Here the gain control is through the variable resistor Rv which
Rv1 Rv2
is divided in two by the slider such that
Out

Rv1 + Rv2 = Rv

Obviously, the gain of the circuit is given by

Rf R2 + Rv2
Gain = − =−
Ri R1 + Rv1
When the slider is at its left extreme, Rv1 = 0 and Rv2 = Rv . The gain is maximum
in this position and is = - R2R+R
1
v
. If R1 = R2 = R, the magnitude of the gain is greater
Rv
than one and is 1 + R . Thus the input signal is amplified.

When the slider is taken to its right extreme, Rv1 = Rv and Rv2 = 0. Again as-
R
suming R1 = R2 = R, the gain is now = - R+R v
This ls less than 1 and thus the input
signal is attenuated. If Rv is an order of magnitude larger than R, a boost or cut of
about 20 dB will be achieved.

We want to make this boost or cut frequency selective. We make use of of the
fact that a capacitor offers low impedance at high frequencies. So if the signal has a
resistive path and a capacitive path, higher frequencies prefer the capacitive path while
the lower frequencies prefer the resistive path. The dividing frequency between high and
low frequency is given by 1/(2πRC). The Baxendall network shown below makes use of
this.

1
 Input Low Feedback
Low + Med. Bass Low + Med.

Low + Med.

Med.

Med.
Rb1 Rb2

Low
Rbm
Cb1 Cb2
In Out

High
Rtm
High
Ct1 Ct2

High Treble High

Input Feedback

To understand its operation, we shall see how the circuit operates at Low, Mid and High
frequencies.

• We first divide the high frequency component of the input signal from Low and
Medium frequencies through the use of Rb1 and Ct1 . The values of Rb1 and Ct1 are
so chosen that the high frequencies prefer the capacitive path and flow through
the lower half of the circuit, while the low and mid frequencies flow through upper
half (through the resistor).

• We further separate the low and medium frequencies through the use of Cb1 and
the bass control +Rbm . The values of Cb1 and Rbm are so chosen that the medium
frequencies flow through the capacitor Cb1 while the low frequencies flow through
the bass control and Rbm .

• The feedback is divided similarly. So the component values are chosen to be sym-
metric, such that Rb1 = Rb2 , Cb1 = Cb2 and Ct1 = Ct2 .

It is easier to understand the operation of the circuit if we trace the path of the three
ranges of frequencies separately. At low frequencies, all capacitors can be taken to be
open circuits. The circuit thus reduces to the following:
Bass

Rb1 Rb2
This can be easily recognized as the boost and
Rbm
cut amplifier discussed in the beginning, with the
In
Low Frequency Path
Out bass control setting the amount of boost and cut,
more or less independent of the other control.

At mid frequencies, Ct1 and Ct2 are seen as open, while the values of Cb1 and Cb2 are
such that the mid frequencies prefer to go through these rather than Rbv and Rbm . The
equivalent circuit at mid frequencies is therefore as given below:
Rb1 Cb1 Cb2 Rb2
Med. Med.
It is clear that the gain is 1 at these frequencies
In
Out
because of symmetric values chosen. This is what
Mid Frequency Path
we want.

At high frequencies, the signal flows through Ct1 , treble control and Ct2 . The circuit
thus becomes as shown below:

2
 Again, this is the same as the gain and boost
In
High Frequency Path
Out
circuit discussed in the beginning and the treble
control decides the amount of boost or cut, more
Rtm High
High High or less independent of the bass control circuitry.
Ct1 Treble Ct2

We can use the same network with a common emitter amplifier rather than using an
opamp. The common emitter amplifier is shown in the following figure:
V CCWe assume that a supply voltage of 9.0 Volts will be used and the
Rbias1 R transistor will be biased at a collector current of about 0.7 mA.
C
Out
CB We choose an emitter voltage of about 1.5V, which requires a resis-
In
CC
tor of 1.5/0.7 ≈ 2.2KΩ. (This gives an emitter voltage of 1.54V.)

Rbias2 RE
To maximize the swing at the output, we would like to place the
CE
collector voltage at nearly halfway between the supply voltage and
emitter voltage.
This implies that the collector voltage will be about 5.27V and therefore the collector
load resistor will be about
9 − 5.27
RC = ≈ 5.3KΩ
0.7
We shall use the commonly available value of 5.6 KΩ.

Assuming a forward drop of about 0.6V across the base emitter junction, the base
voltage is ≈ 1.54 + 0.6 = 2.14 V. Ignoring base current, we can get this voltage by using
a potential divider.
Rbias1 + Rbias2 Rbias2 9
= 1+ = ≈ 4.2
Rbias1 Rbias1 2.14
Therefore we can choose bias resistors in the ratio of about 3.2. We choose bias
resistors of 150 KΩ and 47 KΩ.
This circuit can be simulated in SPICE by the following input file:

Baxendall Tone Control

vin input 0 dc 0 sin(0 0.1 1k) ac .01
vcc VccRail 0 9V
rc VccRail q1coll 5.6k
q1 q1coll q1base q1emitter qnl
re q1emitter 0 2.2k
ce q1emitter 0 500u
rbias1 VccRail q1base 150k
rbias2 q1base 0 47k
* Feedback from collector
c2 q1coll feedback 100u
* Baxendall Network
* Bass Arm
rb1 input basstop 10k
rb2 bassbtm feedback 10k
* (Alternative choices for Bass control)
* (Total resistance of control = 220K)
* Bass cut

3
*rbv1 basstop bslider 210k
*rbv2 bslider bassbtm 10k
* Bass flat
rbv1 basstop bslider 102k
rbv2 bslider bassbtm 118k
* Bass boost
*rbv1 basstop bslider 10k
*rbv2 bslider bassbtm 210k
cbp1 basstop bslider 68n
cbp2 bslider bassbtm 68n
* Treble Arm
ct1 input trebletop 3.9n
ct2 treblebtm feedback 3.9n
* (Alternative choices for Treble control)
* (Total resistance of control = 100K)
* Treble cut
*rtv1 trebletop tslider 99k
*rtv2 tslider treblebtm 1k
* Treble flat
rtv1 trebletop tslider 50k
rtv2 tslider treblebtm 50k
* Treble boost
*rtv1 trebletop tslider 1k
*rtv2 tslider treblebtm 99k

* Centre pt. connections

rbass bslider qinput 1k
rtreb tslider qinput 1k
c1 qinput q1base 10u

.model qnl npn(level=1 bf=150 rb=100 ccs=2pf tf=0.3ns tr=6ns cje=3pf cjc=2pf
+ va=50)
.ac dec 10 10 30khz
.control
run
plot 20*log(abs(V(q1coll))/.01)/log(10) yl -20 +20
.endc

.end

The simulation file contains various options for values of the two halves of the bass
and treble control. We can uncomment only the option we want and leave the other
alternatives commented. Then we run SPICE simulations to see what kind of output is
produced by these.

4
 Units 20*log(abs(v(q1coll))/.01)/log(10)

20.0

When both controls use the “flat” option, we 15.0

should get a gain which is essentially constant 10.0

across the entire audio frequency range. Indeed

5.0

this is what we see when we run the above file us-

0.0

-5.0

ing ngspice. (The gain as a function of frequency

-10.0

is shown as a dashed line).

-15.0

-20.0
10 100 10^3 10^4 10^5

frequency Hz

Units 20*log(abs(v(q1coll))/.01)/log(10)

20.0

Suppose we want to see the behaviour of this cir- 15.0

cuit under maximum bass boost and maximum

10.0

treble cut. We uncomment the corresponding line

5.0

0.0

in the simulation file and re-run ng-spice. As ex-

-5.0

pected, we see the gain versus frequency plot as

-10.0

shown on the right. -15.0

-20.0
10 100 10^3 10^4 10^5

frequency Hz

The low frequency gain is about +15 dB at 20 Hz, while the high frequency gain drops
to -15 dB. The mid frequency gain is around 0 dB as desired.

Units 20*log(abs(v(q1coll))/.01)/log(10)

20.0

15.0

Alternatively, if we want maximum bass cut and 10.0

treble boost, we can choose the appropriate entry 5.0

in the circuit description file and run ngspice with 0.0

it. We now get the characteristics shown on the -5.0

right: -10.0

-15.0

-20.0
10 100 10^3 10^4 10^5

frequency Hz

Units 20*log(abs(v(q1coll))/.01)/log(10)

20.0

Of course, the circuit will work properly with mod- 15.0

erate boost and cut choices as well. One such ex- 10.0

ample with simultaneous boost of bass and treble 5.0

by a moderate amount is shown below: it divides 0.0

the 100K variable resistor for treble into 15K and -5.0

85K, while the 220K variable resistor controlling -10.0

bass is split into 55K and 165K. -15.0

-20.0
10 100 10^3 10^4 10^5

frequency Hz